'Class Module Command
' To be used to Implement as an interface
Option Explicit

Public Sub run()
End Sub

'Class Module SendEmailCommand
Option Compare Database
Option Explicit

Implements Command

Private p_recipient As String
Private p_subject As String
Private p_body As String

Public Sub Init(recipient As String, subject As String, body As String)
    p_recipient = recipient
    p_subject = subject
    p_body = body
End Sub

Private Sub Command_run()
    ' Code to send email
    MsgBox "Sending email to " & p_recipient
End Sub

' Class Module CommandInvoker
Option Compare Database
Option Explicit

Private commands As Collection

Public Sub Init()
    Set commands = New Collection
End Sub

Public Sub AddCommand(cmd As Command)
    commands.Add cmd
End Sub

Public Sub ExecuteCommands()
    Dim cmdIterator As Variant
    Dim cmd As Command
    For Each cmdIterator In commands
        Set cmd = cmdIterator
        cmd.run
    Next cmdIterator
End Sub

' Command Pattern usage test added to a normal Module
Sub UseCommandPattern()
    Dim invoker As New CommandInvoker
    invoker.Init

    Dim emailCommand As New SendEmailCommand
    emailCommand.Init "example@example.com", "Subject", "Body"
    invoker.AddCommand emailCommand

    invoker.ExecuteCommands
End Sub